JJ 6V6s spice model

[marmax]

Hi everyone,

I decided to mix my two passions (electronics and music) and to design my own 5W SE guitar amp.
In order to ensure my calculation is right about bias, distortion and gain, I began spice simulations of my preamp/tone stages based on JJ ECC83.

The next step is to simulate the output stage, and I decided to use the JJ 6V6s pentode. However, after hours of deep search on tens of websites and forums, I couldn't find any spice simulation model for this tube...

I was wondering if anyone did create its own spice model for this tube, and would be ok to share it ?

Thank you by advance for your help...!

[d95err]

Don't know any 6V6 models, sorry!
However, simulations have limited value for designing something as simple as a SE output stage. I think you are better off building it and experimenting, going by your ears rather than simulation.

[nickb]

Agree with the previous comment.

You won't find any model that is specific to a JJ 6V6, the tolerances far exceed the differences between types. This is the best model that I am aware of:

.SUBCKT 6V6GT 1 2 3 4 ; A G2 G1 C;
*      Extract V1.980
* Model created:  7-Jun-2014
* NOTE: LOG(x) is base e LOG or natural logarithm.
* For some Spice versions, e.g. MicroCap, this has to be changed to LN(x).
X1 1 2 3 4 BTetrodeDE  MU= 10.56 EX=1.306 kG1= 609.8 KP=  47.9 kVB = 2171.5 kG2=17267.3
+Sc=.81E-01 ap=  .013 w=    18. nu=   .92 lam=     5.7
+ Ookg1mOokG2=.158E-02 Aokg1=.57E-06 alkg1palskg2=.158E-02 be=  .068 als= 18.72 RGI=2000
+ CCG1=9.0P  CCG2 = 0.0p CPG1 = 0.7p  CG1G2 = 0.0p CCP=7.5P  ;
.ENDS
****************************************************                            
.SUBCKT BTetrodeDE 1 2 3 4; A G2 G1 C                                            
RE1  7 0  1MEG    ; DUMMY SO NODE 7 HAS 2 CONNECTIONS                           
E1 7 0 VALUE=                                                                   
+{V(2,4)/KP*LOG(1+EXP(KP*(1/MU+V(3,4)/SQRT(KVB+V(2,4)*V(2,4)))))}               
E2   8 0 VALUE = {Ookg1mOokG2 + Aokg1*V(1,4) - alkg1palskg2*Exp(-be*V(1,4)*SQRT(be*V(1,4)))}
E3   9 0 VALUE = {Sc/kG2*V(1,4)*(1+tanh(-ap*(V(1,4)-V(2,4)/lam+w+nu*V(3,4))))}  
G1   1 4 VALUE = {0.5*(PWR(V(7),EX)+PWRS(V(7),EX))*(V(8)-V(9))}                                                                     
G2   2 4 VALUE = {0.5*(PWR(V(7),EX)+PWRS(V(7),EX))/KG2 *(1+als*Exp(-be*V(1,4) * SQRT(be*V(1,4))))}
RCP  1 4  1G      ; FOR CONVERGENCE    A  - C                                      
C1   3 4  {CCG1}   ; CATHODE-GRID 1    C  - G1
C4   2 4  {CCG2}   ; CATHODE-GRID 2    C  - G2
C5   2 3  {CG1G2}   ; Grid 1-GRID 2    G1  - G2
C2   1 3  {CPG1}  ; GRID 1-PLATE    G1 - A                                         
C3   1 4  {CCP}   ; CATHODE-PLATE    A  - C                                        
R1   3 5  {RGI}   ; FOR GRID CURRENT    G1 - 5                                     
D3   5 4  DX      ; FOR GRID CURRENT    5  - C                                     
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS BTetrodeDE

[marmax]

Wow, I didn’t expect so quick answers thank you very much !
Actually, I’m a signal and power integrity engineer on multi-GHz digital bobards, and simulation is in my job’s genetics
Still, I completely understand your argument about listening-based design. As I won’t order my design’s parts before a few months I wanted to anticipate the behaviour as much as I could in order to make time run faster
I’ll give a try to nickb’s model just to avoid big calculation mistakes.

Thank you again !

[jazbo8]

6V6S Spice Model

Rename the attachment as .inc

[marmax]

Perfect, thank you VERY much jazbo8
Even if my ears will be the final judge, I will be able to quench my thirst of simulation !

[nickb]

Here is a comparison of the two models ( Derk Reefman and Ayumi Nakabayashi):




The screen current for the Ayumi Nakabayashi model is very high, the datasheet states Ig2=4.5mA for Va=Vs=250 and Vg=-12.5. Also it is starts to reduce at very low plate voltages. The plate current plot has a discontinuity and does not show the typical beam tetrode kink. The Derk model is closer to reality, IMHO.

[bea]

Hard to tell, actually. Simple reason: lack of curves for the 6V6GT.

But here a set of curves for the 6V6GTA: http://www.mif.pg.gda.pl/homepages/f...5/6/6V6GTA.pdf

I'm a bit tired to do an exact comparison - but qualitatively that one appears to be more similar to the Ayumi model. Which mainly demonstrates the importance of knowing the actual reference source for the model...

[SoulFetish]

If you'll forgive my ignorance and indulge me for a moment – Can these models be used within spice to plot operating curves and output graphical data? If so, I would think we could compare these against actual data curves obtained by a µtracer (as an example) as one method of testing accuracy.
But, then again, perhaps you would find the tolerances between individual 6L6 operation to be great enough that it trivializes any differences between these models.
...of course, I could always learn how to use spice and see for myself

[nickb]

If you'll forgive my ignorance and indulge me for a moment – Can these models be used within spice to plot operating curves and output graphical data? If so, I would think we could compare these against actual data curves obtained by a µtracer (as an example) as one method of testing accuracy.
But, then again, perhaps you would find the tolerances between individual 6L6 operation to be great enough that it trivializes any differences between these models.
...of course, I could always learn how to use spice and see for myself

The Derk model above was obtained by curve tracing on a uTrcaer and then best fitting the model to that data.

[SoulFetish]

The Derk model above was obtained by curve tracing on a uTrcaer and then best fitting the model to that data.

Well... that was good thinkin' then. I sure wish I thought of that.